Day 1

lyrics/01.rock

@@ -1,5 +0,0 @@
-Listen to Input
-
-Until Input is wrong
-Say Input
-Listen to Input

lyrics/2020-01-minimal.rock

@@ -0,0 +1,36 @@
+Rock Input
+Listen to Line
+Until Line is gone
+  Cast Line
+  Rock Input with Line
+  Listen to Line
+(end until)
+Test takes Start and Sum and Count
+  Let I be Start
+  Until I is Input minus 1
+    Let Item be Input at I
+    If Item is mysterious
+      Give back nothing
+    (end if)
+    If Count is 1
+      If Item is Sum
+        Give back Item
+      (end if)
+    (end if)
+    If Count is greater than 1 and Item is less than Sum
+      Let St be I plus 1
+      Let Su be Sum minus Item
+      Let Co be Count minus 1
+      Let Result be Test taking St, Su, Co
+      If Result ain't nothing
+        Give back Item times Result
+      (end if)
+    (end if)
+    Build I up
+    Continue
+  (end until)
+  Give back nothing
+(end function)
+
+Say Test taking 0, 2020, 2
+Say Test taking 0, 2020, 3

lyrics/2020-01.rock

@@ -0,0 +1,43 @@
+The path is complicated
+The obstacles are unexpected
+
+Pain is unavoidable-
+The power is in overcoming it completely
+Peace is therapeutic
+Let life be peace with pain
+
+Rock the journey
+Listen to your heart
+Until your heart is empty
+Cast your heart (ahead)
+Rock the journey with your heart
+Listen to your heart
+
+Your journey takes a plan and your hope and time
+Let your focus be a plan
+Until your focus is the journey without the path
+Let the truth be the journey at your focus
+If the truth is mysterious
+Give back nothing
+
+If time is the path
+If your hope is the truth
+Give back the truth
+
+
+If time is greater than the path and the truth is less than your hope
+Let the future be your focus with the path
+Let the past be your hope without the truth
+Let the present be time without the path
+Let everything be your journey taking the future, the past, the present
+If everything ain't nothing
+Give back the truth of everything
+
+
+Build your focus up
+Continue
+
+Give back nothing
+
+Say your journey taking the obstacles, the power, pain
+Shout your journey taking the obstacles, the power, life